魔兽世界10.0战士一键宏

happyxp

10.0更新了，很多以前的宏需要改进下。天赋点来点去，技能变得很多很杂，特分享一些宏给大家，尤其是手小按着吃力，或者想要偷懒的玩家。下面直接上宏：
1、冲锋援护宏
敌方目标冲锋，友方目标援护。鼠标指向目标优先。按住alt或shift或ctrl释放集结呐喊。近战范围战斗、防御专精撕裂，狂暴天赋断筋。同时给土豪玩家添加棱彩装饰。让你成为冲锋最靓的仔。
#showtooltip [mod]集结呐喊;冲锋
/cast [mod]集结呐喊; [@mouseover,help] 援护; [@mouseover,harm] 冲锋; [@target,help] 援护; [@target,harm] 冲锋
/cast [spec:1/3]撕裂;断筋
/use 棱彩装饰

加了武器的碎颅打击和狂暴的强攻，如果点了这两个，近战范围内可以使用这两个技能，省键位的。防护的盾牌冲锋我也加进去了，因为盾牌冲锋近战范围内也能用，我一直当个大技能用，不喜欢的删了盾牌冲锋。
#showtooltip
/cast [mod,known:集结呐喊]集结呐喊;[@mouseover,help,known:援护]援护; [@mouseover,harm] 冲锋; [@target,help,known:援护] 援护;冲锋
/cast [known:盾牌冲锋]盾牌冲锋
/cast [known:碎颅打击]碎颅打击;[known:强攻]强攻;[known:撕裂]撕裂;断筋
/use 棱彩装饰

2、基础近战技能
战斗专精顺序释放“致死打击、猛击”，5s重置；可以根据自己致死打击的冷却时间，自己调节，“reset=5”中的数字更改为冷却时间。狂暴专精怒击，防御专精盾牌猛击。
#showtooltip
/castsequence [spec:1] reset=5 致死打击,猛击
/cast [spec:2]怒击;[spec:3]盾牌猛击

3、基础范围技能
战斗专精顺序释放“顺劈斩、旋风斩”，5s重置，同理上面的，可以自行调节冷却时间(如果没点出顺劈斩则是释放旋风斩，但是图标不显示，你可以手动在#showtooltip后面加上旋风斩)。狂暴专精旋风斩，防御专精雷霆一击和盾牌格挡(盾牌格挡是不占公共cd技能，可以写进宏命令中和其他技能同时释放，可以根据自己喜好写进其他技能中，我个人喜欢和雷霆绑一起，提高盾挡覆盖率，高玩喜欢控怒气请无视此条)。
#showtooltip
/castsequence [spec:1] reset=5 顺劈斩,旋风斩
/cast [spec:3]雷霆一击;[spec:1/2]旋风斩
/cast [spec:3]盾牌格挡

基础aoe技能。这里重点说下武器专精，点了刀剑风暴和收割扫荡之后，顺劈斩只有3s，旋风斩却有12s，所以就不用顺序宏了只留旋风斩。点了收割扫荡之后顺劈斩3s，然后有点了雷霆一击的流血流派，就用了雷霆和旋风斩的顺序宏，节省键位。
#showtooltip
/cast [spec:1,known:刀剑风暴,known:收割扫荡]旋风斩
/castsequence [spec:1,known:收割扫荡,known:雷霆一击] reset=4 雷霆一击,旋风斩
/castsequence [spec:1,known:顺劈斩] reset=5 顺劈斩,旋风斩
/cast [spec:3]雷霆一击;[spec:1/2]旋风斩
/cast [spec:3]盾牌格挡

4、常用专精技能
武器专精压制，狂暴专精嗜血，防御专精复仇。然后绑了个炫光之翼玩具。朴实无华的专精切换宏(凑数用的)
#showtooltip
/cast [spec:1]压制;[spec:2]嗜血;[spec:3]复仇
/use 炫光之翼

防御专精加了个法术格挡，省键位用的。
#showtooltip
/cast [mod,known:法术格挡]法术格挡;[spec:3]复仇;[spec:1]压制;[spec:2]嗜血
/use 炫光之翼

5、输出核心技能和防御的嘲讽
防御专精嘲讽，鼠标指向优先。按住alt或shift或ctrl释放挑战怒吼。战斗专精巨人打击，狂暴专精暴怒。狂暴和战斗专精释放种族技能(种族爆发技能不占公共cd，那些带爆发的种族技能，嫌不够的自己可以再加两条吧)
#showtooltip [mod,spec:3]挑战怒吼[spec:3]嘲讽;[spec:1]巨人打击;[spec:2]暴怒
/cast [spec:1/2,combat]血性狂怒
/cast [spec:1/2,combat]狂暴
/cast [spec:1/2,combat]先祖召唤
/cast [mod,spec:3]挑战怒吼;[spec:3,@mouseover,harm,exists][spec:3]嘲讽;[spec:1]巨人打击;[spec:2]暴怒

核心输出和嘲讽。这里点了收割扫荡就是顺劈斩，没点就是巨人打击。
#showtooltip [mod,spec:3]挑战怒吼;[spec:1,known:收割扫荡]顺劈斩;[spec:1]巨人打击;[spec:2]暴怒;[spec:3]嘲讽
/cast [spec:1/2,combat]狂暴
/cast [mod,spec:3]挑战怒吼;[spec:1,known:收割扫荡]顺劈斩;[spec:1]巨人打击;[spec:2]暴怒;[spec:3,@mouseover,harm,exists][spec:3]嘲讽

6、专精深天赋技能宏(这边的是把可能用到的写进宏了，估计这里的技能蛮少会点出来的，爱用不用吧)。
战斗专精碎颅打击，狂暴专精强攻，防御专精盾牌冲锋。按住alt或shift或ctrl，战斗专精剑刃风暴，狂暴和防御专精破坏者。如果碎颅打击、强攻、盾牌冲锋没点出来，那么直接就是释放剑刃风暴、破坏者，但是技能不显示，如果嫌难看可以在#showtooltip后面加上技能名称，反正不影响使用。
#showtooltip
/cast [mod,spec:1]剑刃风暴;[mod,spec:2/3]破坏者;[spec:1]碎颅打击;[spec:2]强攻;[spec:3]盾牌冲锋
/cast [spec:1]剑刃风暴;[spec:2/3]破坏者

专精深层天赋。同上，点了收割扫荡就是巨人打击，没点就是剑刃风暴。剑刃风暴再单独设个按键吧。
#showtooltip
/cast [mod,known:破胆怒吼]破胆怒吼;[spec:1,known:收割扫荡]巨人打击;[spec:1]剑刃风暴;[spec:2,@player,combat]破坏者;[spec:2,@cursor]破坏者;[spec:3]挫志怒吼

7、打断宏
打断，优先焦点目标。按住alt或shift或ctrl释放风暴之锤。远距离释放英勇投掷。
#showtooltip
/cast [mod]风暴之锤; [@focus,exists,nodead] 拳击;拳击
/cast 英勇投掷

打断及点控。没什么变化。
#showtooltip
/cast [mod,known:风暴之锤]风暴之锤; [@focus,exists,nodead] 拳击;拳击
/cast 英勇投掷

8、乘胜追击宏
战斗专精释放横扫攻击和法术反射(法术反射是不占公共cd技能)，按住alt或shift或ctrl释放剑在人在和乘胜追击(剑在人在是不占公共cd技能)。狂暴专精释放乘胜追击和法术反射，按住alt或shift或ctrl释放狂怒回复。防御专精释放乘胜追击和无视痛苦，按住alt或shift或ctrl释放破釜沉舟(其实如果最后一条不加条件，法术反射也能一起放，但是防战法术反射还是蛮需要用来躲一些特别技能，全自动实在有点说不过去，其他两个专精就无所谓了)。
#showtooltip
/cast [mod,spec:1]剑在人在;[mod,spec:2]狂怒回复;[mod,spec:3]破釜沉舟;[spec:1]横扫攻击;[spec:2]乘胜追击
/cast [spec:3]无视苦痛
/cast [mod,spec:1]乘胜追击
/cast [spec:1/2]法术反射

小减伤。这里改了下，狂暴专精放了奥丁之怒。键位紧张。然后把姿态切换拆开绑了这个和爆发坐骑宏。此外，由于这版本大多会点出胜利在望，所以乘胜追击就没办法用出来了(乘胜追击没公cd，但是胜利在望有)，需要单独设置一个键位。防战不影响，因为无视痛苦没公cd。
#showtooltip
/cast [spec:1/2,known:防御姿态,nostance:1,mod]防御姿态;[spec:3,nostance:1]防御姿态
/cast [mod,spec:1]剑在人在; [mod,spec:2]狂怒回复;[mod,spec:3]破釜沉舟;[spec:1]横扫攻击;[spec:2]奥丁之怒;[spec:3]无视苦痛
/cast 乘胜追击
/cast [spec:1/2]法术反射

9、大爆发技能及坐骑宏
这个宏分两个部分，非战斗状态下，随机召唤偏好坐骑，按住alt或shift或ctrl召唤雄壮远足牦牛(有雷龙的可以替换，或者用alt，ctrl，shift分下，本人穷逼没有，所以也不写了)和战斗怒吼(这样战斗怒吼就不会忘记补了)。战斗状态下为现版本的大爆发技能“天神下凡”(目前应该没有不点天神的天赋吧，且天神下凡是不占公共cd技能)，狂暴专精下鲁莽(鲁莽也是不占公共cd技能)，种族爆发技能(同上)，和雷鸣之吼(目前貌似没看到有人点这个，但是先写着吧，不碍事。)，使用饰品2(最后一条use 14看你需求，爆发绑饰品就用，不想绑就删了)。
刚开游戏又试了几次，发现如果带了痛苦之王橙，貌似只会释放天神下凡，但是天神cd中的话，宏里的其他技能也能释放，不知道是什么bug，反正这个橙很快也用不到了，不管它了
#showtooltip [combat]天神下凡;迅捷祖利安猛虎
/castrandom [combat]天神下凡;[outdoors,nocombat,mod]雄壮远足牦牛
/run C_MountJournal.SummonByID(0)
/dismount [mounted]
/cast [spec:2,combat]鲁莽
/cast [combat]血性狂怒
/cast [combat]狂暴
/cast [combat]先祖召唤
/cast [combat]雷鸣之吼
/use [combat]14
/cast 战斗怒吼

大爆发及坐骑宏。这里把姿态切换拆开了，但是由于255字符数限制，有一部分拆到了斩杀宏里去了。但也没啥影响。
#showtooltip
/cast [spec:1,nostance][spec:3,nostance:2,combat]战斗姿态;[spec:2,nostance]狂暴姿态
/cast [mod]雄壮远足牦牛;[combat]天神下凡
/run C_MountJournal.SummonByID(0)
/cast [combat]鲁莽
/cast [combat]狂暴
/use [combat]14
/cast [combat]雷鸣之吼
/cast 战斗怒吼

10、两个怒吼
都点了就释放刺耳怒吼，按住alt或shift或ctrl释放破胆怒吼。如果两个只点一个的，就在#showtooltip后面加上点了的技能名称，不然显示技能名称不完整。但是这版本好像没见点这两个天赋的，和第6条一样大概率用不上。
#showtooltip
/cast [mod]破胆怒吼;[spec:3]挫志怒吼;刺耳怒吼
/cast 破胆怒吼

大长cd技能
#showtooltip
/cast [mod,known:苦痛免疫]苦痛免疫;[spec:3,mod]盾墙;[spec:1/2,known:晋升堡垒之矛,@player,combat]晋升堡垒之矛;[spec:1/2,known:晋升堡垒之矛,@cursor]晋升堡垒之矛;[spec:1/2,known:雷鸣之吼]雷鸣之吼;[spec:2/3,@cursor]破坏者

11、斩杀宏
取消保护祝福放在这个宏里，哪位有爱的qs大爷给了保护祝福可以这里点掉，防御专精，按住alt或ctrl或shift释放震荡波。然后释放饰品1(最后一条use 13看你需求，不想绑就删了)。
#showtooltip
/cancelaura 保护祝福
/cast [mod,spec:3]震荡波;斩杀
/use [nomod,combat]13

斩杀。拆了部分姿态切换宏出来，两输出专精点了防御姿态的话，可以按这个切换回去。此外，加了个战旗飘扬，当玩具用。
#showtooltip
/cast [spec:1,known:防御姿态,nostance:2]战斗姿态;[spec:2,known:防御姿态,nostance:2]狂暴姿态
/cancelaura 保护祝福
/cancelaura 剑刃风暴
/cast [mod,known:震荡波]震荡波;[combat]斩杀
/cast !战旗飘扬(通灵领主)
/use [combat]13

12、姿态宏
这个版本的最新宏。就两个姿态之间切换，建议配合监控姿态的wa使用，效果更佳。
#showtooltip
/cast [spec:1/2,stance:2]防御姿态;[spec:3,stance:1]战斗姿态;[spec:1]!战斗姿态;[spec:2]!狂暴姿态;[spec:3]!防御姿态

13、盟约技能宏
属于接下来就没用，但是现阶段还蛮有用的宏。其中第一个里还绑了防御专精的盾墙和苦痛免疫(不过貌似这个天赋没人点，等大佬们开发开发)。
#showtooltip
/cast [mod,spec:3]盾墙;[combat,@cursor]晋升堡垒之矛;晋升堡垒之矛
/cast [mod,spec:3]盾墙;征服者战旗
/cast [mod,spec:3]盾墙;上古余震
/cast [mod]苦痛免疫
/run local G=GetSpellInfo SetMacroSpell(GetRunningMacro(), G"晋升堡垒之矛" or G"征服者战旗" or G"上古余震")
这个是盟约通用技能宏。
#showtooltip
/cast 暗影之门
/cast 灵魂变形
/cast 血肉铸造
/use [combat]静谧之瓶;召唤执事者
/run local G=GetSpellInfo SetMacroSpell(GetRunningMacro(), G"暗影之门" or G"灵魂变形" or G"血肉铸造"or G"召唤执事者")

14、鼠标指向英勇飞跃宏(凑数的)
#showtooltip
/cast [@cursor] 英勇飞跃

15、鼠标指向优先的碎裂投掷宏(同样是凑数的)
#showtooltip
/cast [@mouseover] 碎裂投掷;碎裂投掷

不常点出的技能合并。碎裂投掷、刺耳怒吼和狂暴之怒，点了的话可以用下，估计狂暴之怒偶尔会点出来用用。
#showtooltip
/cast [@mouseover,known:碎裂投掷] 碎裂投掷;[known:刺耳怒吼]刺耳怒吼;[known:狂暴之怒]狂暴之怒;风暴之锤

16、退组宏，潇洒退组，不用右键选半天。
/script C_PartyInfo.LeaveParty()

魔兽世界常用宏命令基础入门
魔兽世界随机玩具炉石宏怎么写？炉石玩具ID一览

本文原文来自NGA，感谢原作者UID:62290408